/****************************************************************************
**
** Copyright (C) 2011 Nokia Institute of Technology.
** All rights reserved.
** Contact: Manager (renato.chencarek@openbossa.org)
**
** This file is part of the Incredible Circus project.
**
** GNU Lesser General Public License Usage
**
** This file may be used under the terms of the GNU Lesser General Public
** License version 2.1 as published by the Free Software Foundation and
** appearing in the file LICENSE.LGPL included in the packaging of this
** file. Please review the following information to ensure the GNU Lesser
** General Public License version 2.1 requirements will be met:
** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
**
****************************************************************************/

import QtQuick 1.1
import "widgets"

Item {
    id: root

    signal playClicked()

    Item {
        id: content
        anchors.fill: parent

        ImageButton {
            anchors.top: parent.top
            anchors.left: parent.left
            anchors.topMargin: 6
            onClicked: root.state = "about";
            source: "image://cache/screens/main/info.png"
        }

        ImageButton {
            anchors.top: parent.top
            anchors.right: parent.right
            anchors.topMargin: 6
            onClicked: Qt.openUrlExternally("https://touch.facebook.com/incrediblecircus");
            source: "image://cache/screens/main/facebook.png"
        }

        Image {
            anchors.top: parent.top
            anchors.topMargin: 26
            anchors.horizontalCenter: parent.horizontalCenter
            source: "image://cache/common/circus_title.png"
        }

        Frame {
            id: frameView
            anchors.verticalCenter: parent.verticalCenter
            anchors.horizontalCenter: parent.horizontalCenter

            title: qsTr("Menu")
            background: "image://cache/common/frameback.png"

            Image {
                source: "image://cache/screens/main/player_logo.png"
                anchors.bottom: parent.bottom
                anchors.horizontalCenter: parent.horizontalCenter
            }
        }

        BottomBar {
            Button {
                text: qsTr("Quit")
                onClicked: Qt.quit()
            }
            ImageButton {
                onClicked: sound.enabled = !sound.enabled
                source: sound.enabled ? "image://cache/buttons/bt_song.png"
                    : "image://cache/buttons/bt_song_off.png"
            }
            Button {
                text: qsTr("Play")
                onClicked: root.playClicked()
            }
        }
    }

    AboutScreen {
        id: about
        opacity: 0.0
        visible: false
        anchors.fill: parent
        onBackClicked: root.state = "";
    }

    states: State {
        name: "about"
        PropertyChanges { target: content; visible: false; }
        PropertyChanges { target: about; opacity: 1.0; visible: true; }
    }

    transitions: Transition {
        to: "about"
        reversible: true
        SequentialAnimation {
            PropertyAction { target: about; property: "visible"; }
            NumberAnimation { target: about; properties: "opacity"; duration: 600; }
            PropertyAction { target: content; property: "visible"; }
        }
    }
}