/****************************************************************************
**
** Copyright (C) 2011 Nokia Institute of Technology.
** All rights reserved.
** Contact: Manager (renato.chencarek@openbossa.org)
**
** This file is part of the Incredible Circus project.
**
** GNU Lesser General Public License Usage
**
** This file may be used under the terms of the GNU Lesser General Public
** License version 2.1 as published by the Free Software Foundation and
** appearing in the file LICENSE.LGPL included in the packaging of this
** file. Please review the following information to ensure the GNU Lesser
** General Public License version 2.1 requirements will be met:
** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
**
****************************************************************************/

import QtQuick 1.1

Item {
    id: root
    anchors.fill: parent

    signal finished()

    Image {
        id: background
        opacity: 0.0
        visible: false
        anchors.fill: parent
        fillMode: Image.Tile
        source: "image://cache/common/bg.png"

        Image {
            id: newspaper
            scale: 1.6
            rotation: 1
            source: "image://cache/_intro/newspaper/news.png"
            anchors.verticalCenter: parent.verticalCenter
            anchors.horizontalCenter: parent.horizontalCenter
        }
    }

    states: State {
        name: "final"
        PropertyChanges { target: newspaper; scale: 1.0; rotation: 0; }
        PropertyChanges { target: background; opacity: 1.0; visible: true; }
    }

    transitions: Transition {
        to: "final"

        SequentialAnimation {
            PropertyAction { target: background; properties: "visible"; }

            ParallelAnimation {
                NumberAnimation { target: background; duration: 400; properties: "opacity"; }
                NumberAnimation { target: newspaper; duration: 600; properties: "scale"; }
                RotationAnimation { target: newspaper; duration: 600; properties: "rotation";
                                    direction: RotationAnimation.Clockwise; }
            }

            // wait before hiding the menu
            PauseAnimation { duration: 2500; }
            ScriptAction { script: root.finished(); }
        }
    }

    Component.onCompleted: root.state = "final";
}